From 88cfcf1f7b17c46322ebef7f6a38b6c9cac454c2 Mon Sep 17 00:00:00 2001
From: Fredrik Eriksson <feffe@fulh.ax>
Date: Fri, 28 Oct 2022 14:41:04 +0200
Subject: [PATCH] add gammastep ebuild

---
 gui-apps/gammastep/Manifest               |  2 +
 gui-apps/gammastep/gammastep-2.0.9.ebuild | 87 +++++++++++++++++++++++
 2 files changed, 89 insertions(+)
 create mode 100644 gui-apps/gammastep/Manifest
 create mode 100644 gui-apps/gammastep/gammastep-2.0.9.ebuild

diff --git a/gui-apps/gammastep/Manifest b/gui-apps/gammastep/Manifest
new file mode 100644
index 0000000..751ee25
--- /dev/null
+++ b/gui-apps/gammastep/Manifest
@@ -0,0 +1,2 @@
+DIST gammastep-2.0.9.tar.bz2 540120 BLAKE2B cfc29b157ad2dbd3d6bb0ac4bdb26c958ba07cad3e817931c2ee4c2e4d15c157b7c0b8b891869ddcc2cdfc39c1d52afb8437991ae60501afee84500e1f28c694 SHA512 d8b23e5890d6135cef79057408e1b7c1dbc36444dfbfaf7c80a3f36c46df19eaded1829c2cd52365413779cc752d0911a44669b5abce16d7e266b92b15c035fb
+EBUILD gammastep-2.0.9.ebuild 2001 BLAKE2B b5d2f55237c270bae3f15c2c1f884d36d7c9f76b4ef7b9985d425d7f1cbb0afdb4d8d4f9e4447b9d6572137a211b130981ed5c7d7fa8050590e4075fefca5076 SHA512 53443fb17f7124b88d49bedf226a2056b1072927d7e0efab4f73ef7495ab96c30c7133d3f551764b2486375156fdb0de8867e9e14791a3ca9a1265525a4b20c0
diff --git a/gui-apps/gammastep/gammastep-2.0.9.ebuild b/gui-apps/gammastep/gammastep-2.0.9.ebuild
new file mode 100644
index 0000000..997cb5a
--- /dev/null
+++ b/gui-apps/gammastep/gammastep-2.0.9.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..11} )
+
+inherit systemd autotools gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="https://gitlab.com/chinstrap/gammastep/"
+SRC_URI="https://gitlab.com/chinstrap/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2 -> ${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="X appindicator drm geoclue gtk nls wayland"
+
+BDEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+"
+DEPEND="
+	X? (
+		>=x11-libs/libX11-1.4
+		x11-libs/libXxf86vm
+		x11-libs/libxcb
+	)
+	appindicator? ( dev-libs/libappindicator:3[introspection] )
+	drm? ( x11-libs/libdrm )
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )
+	wayland? ( >=dev-libs/wayland-1.15.0 )"
+RDEPEND="${DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+S="${WORKDIR}/${PN}-v${PV}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use gtk && python_setup
+
+	econf \
+		$(use_enable nls) \
+		$(use_enable drm) \
+		$(use_enable X randr) \
+		$(use_enable X vidmode) \
+		$(use_enable geoclue geoclue2) \
+		$(use_enable gtk gui) \
+		$(use_enable wayland) \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
+		--enable-apparmor
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/gammastep_indicator install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/gammastep-indicator
+
+		python_foreach_impl python_optimize
+	fi
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}